Mikrotik - Configuraciones de los principales operadores de fibra óptica
Podemos tener aquí una buena base para cuando nos toque cambiar de proveedor y queramos seguir usando nuestros equipos Mikrotik como los equipos principales de nuestra red.
Para no liarnos, vamos a partir de la configuración base que montaría un quick set: equipo con IP 192.168.88.1/24 y trabajando como router neutro. A partir de ahí, vamos a poner los comandos que necesitaríamos para dejar el router funcionando con cada ISP.
Pepephone
Tipo de conexión WAN: DHCP
VLAN Internet: 20
VLAN Teléfono: N/A
VLAN TV: N/A
Código:
# Damos de alta la vlan correspondiente, asociada al puerto físico que haga de WAN. Suponemos ether1
/interface vlan add interface=ether1 name=internet vlan-id=20
# Creamos (o editamos el existente) cliente DHCP y la asignamos a esa nueva interfaz vlan
/ip dhcp-client add disabled=no interface=internet use-peer-dns=yes use-peer-ntp=yes
# Añadimos la nueva vlan a la lista WAN, para que el firewall/nat funcione correctamente
/interface list member add interface=internet list=WAN
02
Tipo de conexión WAN: PPPoE: usuario (adslppp@telefonicanetpa) y contraseña (adslppp)
VLAN Internet: 6
VLAN Teléfono: 3
VLAN TV: N/A
Código:
# Dar de alta las vlans 3 voip y 6 internet.
/interface vlan
add interface=ether1 name=vlan3 vlan-id=3
add interface=ether1 name=vlan6 vlan-id=6
# Configurar la interfaz PPPoE para que use la VLAN 6 internet.
/interface pppoe-client
add add-default-route=yes allow=pap,chap disabled=no interface=vlan6 \
keepalive-timeout=60 max-mru=1492 max-mtu=1492 name=pppoe-out1 password=\
adslppp use-peer-dns=yes user=adslppp@telefonicanetpa
# Añadimos a la lista WAN el interface PPPoE para que el firewall/nat funcione correctamente.
/interface list member
add interface=pppoe-out1 list=WAN
# Crear un cliente dhcp para la vlan 3 del teléfono voip.
/ip dhcp-client
add add-default-route=no dhcp-options=hostname,clientid disabled=no interface=vlan3 use-peer-ntp=no
# Establecer la prioridad de las conexiones vlans.
/ip firewall mangle
add action=set-priority chain=postrouting new-priority=4 out-interface=vlan3
add action=set-priority chain=postrouting new-priority=1 out-interface=pppoe-out1
# Aceptar el tráfico de entrada para la vlan3 en el firewall
/ip firewall filter
add action=accept chain=input comment="Acepta el trafico de la vlan del telefono" \
in-interface=vlan3 src-address=10.0.0.0/8 \
place-before=[find where chain=input and comment="defconf: drop invalid"]
# Enmascarar las conexiones PPPoE y vlan3 voip.
/ip firewall nat
add action=masquerade chain=srcnat comment="default configuration" \
out-interface=pppoe-out1
add action=masquerade chain=srcnat comment="default configuration" \
out-interface=vlan3
# Puertos del servicio voip.
/ip firewall service-port
set sip disabled=yes ports=5060,5070
# Añadir la vlan 3 de voz protocolo RIP.
/routing rip interface
add interface=vlan3 passive=yes receive=v2
# Indicar la red en la que correrá RIP.
/routing rip network
add network=10.0.0.0/8
Movistar Triple Play
Configuración para un único desco, con ether2 como puerto dedicado, partiendo de la configuración base del quick set.
Tipo de conexión WAN: PPPoE: usuario (adslppp@telefonicanetpa) y contraseña (adslppp)
VLAN Internet: 6
VLAN Teléfono: 3
VLAN TV: 2
Código:
# Editamos el bridge principal para que sea
# compatible con Hardware Offloading
# para equipos con switch-chip MT7621
/interface bridge set bridge protocol-mode=none
# Sacamos ether2 del bridge, para usarlo en exclusivo con el desco
/interface bridge port remove numbers=[find interface=ether2]
# Añadimos las VLANs asociadas al puerto WAN
/interface vlan
add interface=ether1 name=internet-vlan6 vlan-id=6
add interface=ether1 name=iptv-vlan2 vlan-id=2
add interface=ether1 name=voip-vlan3 vlan-id=3
# Creamos el cliente PPPoE sobre la vlan6
/interface pppoe-client
add add-default-route=yes allow=pap,chap disabled=no interface=internet-vlan6 \
keepalive-timeout=60 max-mru=1492 max-mtu=1492 name=pppoe-out1 password=\
adslppp use-peer-dns=yes user=adslppp@telefonicanetpa
# Añadimos una nueva lista donde meteremos las vlans 2 y 3
/interface list
add comment="Vlan2 (Iptv) & Vlan3 (Voip)" name=Vlan2&3
# Metemos cada interfaz en su lista correspondiente
/interface list member
add interface=pppoe-out1 list=WAN
add interface=iptv-vlan2 list=Vlan2&3
add interface=voip-vlan3 list=Vlan2&3
add interface=ether2 list=LAN
# Añadimos la opción especial para el dhcp del desco
/ip dhcp-server option
add code=240 name=option_para_deco value=\
"':::::239.0.2.10:22222:v6.0:239.0.2.30:22222'"
# Añadimos un nuevo pool para IPTV
/ip pool
add name=iptv-pool ranges=192.168.77.195-192.168.77.200
# Damos de alta una nueva red para el servidor dhcp del deco, con un dns concreto de telefónica
/ip dhcp-server network
add address=192.168.77.0/24 dhcp-option=option_para_deco dns-server=\
172.26.23.3 gateway=192.168.77.1 netmask=24
# Creamos un nuevo servidor dhcp para IPTV
/ip dhcp-server
add address-pool=iptv-pool disabled=no interface=ether2 name=iptv-dhcp-server
# Añadir la ip de IPTV, extraída de un backup del router
# Más info, aquí: https://alexariza.net/tutorial/como-obtener-los-datos-de-iptv-con-movistar/
# Sustituir el valor correspondiente en 10.XX.XX.XX/ZZ
/ip address
add address=10.XX.XX.XX/ZZ comment="My Telefonica's IPTV address, from NOLTARI" interface=\
iptv-vlan2 network=10.128.0.0
add address=192.168.77.1/24 comment="IPTV subnet" interface=ether2 network=\
192.168.77.0
# Añadimos un cliente dhcp para obtener la IP del teléfono
/ip dhcp-client
add add-default-route=no disabled=no interface=voip-vlan3 use-peer-ntp=no
# Añadimos tres nuevas reglas al firewall para que funcionen las vlans,
# dos en el chain de input, para aceptar el tráfico de VoIP e IPTV
# y una en el chain de forward para prohibir el tráfico unicast que
# no esté ya nateado
/ip firewall filter
add action=accept chain=input comment="Accept vlan2 Iptv IGMP packets" \
in-interface=iptv-vlan2 protocol=igmp \
place-before=[find where chain=input and comment="defconf: drop invalid"]
add action=accept chain=input comment=\
"Accept vlan2 & 3 (Iptv & Voip) multicast & broadcast traffic" \
dst-address-type=!unicast in-interface-list=Vlan2&3 \
place-before=[find where chain=input and comment="defconf: drop invalid"]
add action=drop chain=forward comment=\
"Drop all new unicast traffic from vlan3 & 2 (Voip & Iptv) not DSTNATed" \
connection-nat-state=!dstnat connection-state=new dst-address-type=\
unicast in-interface-list=Vlan2&3
# Marcamos la prioridad de cada una de las VLANs, usando mangle, postrouting
/ip firewall mangle
add action=set-priority chain=postrouting comment="Prioritise Voip packets" \
new-priority=5 out-interface=voip-vlan3 passthrough=yes
add action=set-priority chain=postrouting comment="Prioritise Iptv packets" \
new-priority=4 out-interface=iptv-vlan2 passthrough=yes
add action=set-priority chain=postrouting new-priority=1 out-interface=\
pppoe-out1
# Además del masquerade a la lista WAN (defconf), añadimos los masquerade
# tanto para ambas vlans como una regla dst-nat para el tráfico del desco
# IMPORTANTE: Si cambia la IP del desco por la asignación del DHCP, hay
# que modificarla en esa regla de NAT
/ip firewall nat
add action=masquerade chain=srcnat comment=\
"masq. vlan2 & vlan3 (Iptv & Voip)" out-interface-list=Vlan2&3
add action=dst-nat chain=dstnat comment="VOD Movistar 1 Desco" dst-address-type=local \
in-interface=iptv-vlan2 to-addresses=192.168.77.200
# Activamos el IGMP-Proxy
/routing igmp-proxy
set query-interval=30s quick-leave=yes
# Configuramos el IGMP-proxy para la interfaz vlan de IPTV y para ether2
/routing igmp-proxy interface
add alternative-subnets=0.0.0.0/0 interface=iptv-vlan2 upstream=yes
add interface=ether2
# Activamos RIP para VoIP e IPTV
/routing rip interface
add interface=voip-vlan3 passive=yes receive=v2
add interface=iptv-vlan2 passive=yes receive=v2
/routing rip network
add network=10.0.0.0/8
add network=172.26.0.0/16
Movistar Triple Play
Configuración multi desco, multi-bridge, partiendo de la configuración base del quick set.
Tipo de conexión WAN: PPPoE: usuario (adslppp@telefonicanetpa) y contraseña (adslppp)
VLAN Internet: 6
VLAN Teléfono: 3
VLAN TV: 2
Código:
# Editamos el bridge principal para que sea
# compatible con Hardware Offloading
# para equipos con switch-chip MT7621
/interface bridge set bridge protocol-mode=none
# Sacamos ether2 del bridge principal
/interface bridge port remove numbers=[find interface=ether2]
# Creamos el nuevo bridge para IPTV
/interface bridge
add name=bridge-iptv igmp-snooping=yes
# Añadimos el puerto ether2 al nuevo bridge
# Si se desa usar más de un puerto para conectar dos descos
# por cable, quitarlos del bridge principal y asignarlos a este
/interface bridge port add bridge=bridge-iptv interface=ether2
# Añadimos las VLANs asociadas al puerto WAN
/interface vlan
add interface=ether1 name=internet-vlan6 vlan-id=6
add interface=ether1 name=iptv-vlan2 vlan-id=2
add interface=ether1 name=voip-vlan3 vlan-id=3
# Creamos el cliente PPPoE sobre la vlan6
/interface pppoe-client
add add-default-route=yes allow=pap,chap disabled=no interface=internet-vlan6 \
keepalive-timeout=60 max-mru=1492 max-mtu=1492 name=pppoe-out1 password=\
adslppp use-peer-dns=yes user=adslppp@telefonicanetpa
# Añadimos una nueva lista donde meteremos las vlans 2 y 3
/interface list
add comment="Vlan2 (Iptv) & Vlan3 (Voip)" name=Vlan2&3
# Metemos cada interfaz en su lista correspondiente
/interface list member
add interface=pppoe-out1 list=WAN
add interface=iptv-vlan2 list=Vlan2&3
add interface=voip-vlan3 list=Vlan2&3
add interface=bridge-iptv list=LAN
# Añadir la ip de IPTV, extraída de un backup del router
# Más info, aquí: https://alexariza.net/tutorial/como-obtener-los-datos-de-iptv-con-movistar/
# Sustituir el valor correspondiente en 10.XX.XX.XX/ZZ
/ip address
add address=10.XX.XX.XX/ZZ comment="My Telefonica's IPTV address, from NOLTARI" interface=\
iptv-vlan2 network=10.128.0.0
add address=192.168.77.1/24 comment="IPTV subnet" interface=bridge-iptv network=\
192.168.77.0
# Añadimos la opción especial para el dhcp del desco
/ip dhcp-server option
add code=240 name=option_para_deco value=\
"':::::239.0.2.10:22222:v6.0:239.0.2.30:22222'"
# Añadimos un nuevo pool para los descos,
# y otro para el resto de los hosts en ese bridge-iptv
/ip pool
add name=pool-iptv-descos ranges=192.168.77.201-192.168.77.206
add name=pool-iptv-hosts ranges=192.168.77.50-192.168.77.199
# Damos de alta una nueva red para los hosts del nuevo bridge-iptv,
# y otra específica para los descos, con una dirección /29
/ip dhcp-server network
add address=192.168.77.0/24 comment="IPTV subnet for hosts" gateway=192.168.77.1 \
netmask=24
add address=192.168.77.200/29 comment="IPTV subnet for descos" \
dhcp-option=option_para_deco dns-server=172.26.23.3 gateway=192.168.77.1 \
netmask=24
# Creamos un nuevo servidor dhcp, asociado al nuevo bridge-iptv
/ip dhcp-server
add address-pool=pool-iptv-hosts disabled=no interface=bridge-iptv name=dhcp-server-iptv
# Asignamos el vendor-class al nuevo servidor IPTV, para los descos
/ip dhcp-server vendor-class-id
add address-pool=pool-iptv-descos name="Movistar Descos" server=dhcp-server-iptv vid="[IAL]"
# Añadimos un cliente dhcp para obtener la IP del teléfono
/ip dhcp-client
add add-default-route=no disabled=no interface=voip-vlan3 use-peer-ntp=no
# Añadimos tres nuevas reglas al firewall para que funcionen las vlans,
# dos en el chain de input, para aceptar el tráfico de VoIP e IPTV
# y una en el chain de forward para prohibir el tráfico unicast que
# no esté ya nateado
/ip firewall filter
add action=accept chain=input comment="Accept vlan2 Iptv IGMP packets" \
in-interface=iptv-vlan2 protocol=igmp \
place-before=[find where chain=input and comment="defconf: drop invalid"]
add action=accept chain=input comment=\
"Accept vlan2 & 3 (Iptv & Voip) multicast & broadcast traffic" \
dst-address-type=!unicast in-interface-list=Vlan2&3 \
place-before=[find where chain=input and comment="defconf: drop invalid"]
add action=drop chain=forward comment=\
"Drop all new unicast traffic from vlan3 & 2 (Voip & Iptv) not DSTNATed" \
connection-nat-state=!dstnat connection-state=new dst-address-type=\
unicast in-interface-list=Vlan2&3
# Marcamos la prioridad de cada una de las VLANs, usando mangle, postrouting
# Además, creamos una lista para identificar las IPs de los los receptores
# de video bajo demanda, los descos.
/ip firewall mangle
add action=set-priority chain=postrouting comment="Prioritise Voip packets" \
new-priority=5 out-interface=voip-vlan3 passthrough=yes
add action=set-priority chain=postrouting comment="Prioritise Iptv packets" \
new-priority=4 out-interface=iptv-vlan2 passthrough=yes
add action=set-priority chain=postrouting new-priority=1 out-interface=\
pppoe-out1
add action=add-src-to-address-list address-list=vod-receiver \
address-list-timeout=1m chain=postrouting comment="RTSP - VOD Movistar" \
connection-state=new dst-port=554 out-interface=iptv-vlan2 protocol=tcp
# Además del masquerade a la lista WAN (defconf), añadimos los masquerade
# para las vlans de voz e iptv, y para los hosts conectados al bridge IPTV
# El script añadirá una regla adicional de masquerade, para los descos
# que vienen de la lista vod-receiver, dada de alta en magle previamente
# con el comentario "VOD Script"
/ip firewall nat
add action=masquerade chain=srcnat comment=\
"masq. vlan2 & vlan3 (Iptv & Voip)" out-interface-list=Vlan2&3
add action=masquerade chain=srcnat comment=\
"masq. IPTV hosts" src-address=192.168.77.0/24
# Activamos el IGMP-Proxy
/routing igmp-proxy
set query-interval=30s quick-leave=yes
# Configuramos el IGMP-proxy para la interfaz vlan de IPTV y para ether2
/routing igmp-proxy interface
add alternative-subnets=0.0.0.0/0 interface=iptv-vlan2 upstream=yes
add interface=bridge-iptv
# Activamos RIP para VoIP e IPTV
/routing rip interface
add interface=voip-vlan3 passive=yes receive=v2
add interface=iptv-vlan2 passive=yes receive=v2
/routing rip network
add network=10.0.0.0/8
add network=172.26.0.0/16
# Script de Toniros para añadir la regla de src-NAT dinámicamente
/system script
add dont-require-permissions=no name=vod owner=admin policy=read,write \
source=":local iplist [:len [/ip firewall address-list find list=\"vod-rec\
eiver\"]]\
\n:local rules [:len [/ip firewall nat find where comment=\"VOD Script\"]]\
\n#:log info \"VODScript: IPs in list are \$iplist !\"\
\n#:log info \"VODScript: Rules are \$rules !\"\
\n:if (\$iplist = 0 and \$rules > 0) do={\
\n\t#/ip firewall nat remove [find comment=\"VOD Script\"];\
\n\t#:log info \"VODScript: Rule removed !\"\
\n} else {\
\n\t:local ipadressnew [/ip firewall address-list get [:pick [/ip firewall\
\_address-list find list=\"vod-receiver\"] (\$iplist-1)] address]\
\n\t:local ipadressold \"None\"\
\n\t#:log info \"VODScript: IP address new is \$ipadressnew !\"\
\n\t:if (\$iplist > 0 ) do {\
\n\t\tif (\$rules > 0 ) do {\
\n\t\t\t:set ipadressold [/ip firewall nat get [find comment=\"VOD Script\
\"] to-addresses] \
\n\t\t\t#:log info \"VODScript: IP address old is \$ipadressold !\"\
\n\t\t}\
\n\t\t:if (\$ipadressnew != \$ipadressold) do={\
\n\t\t\tif (\$rules > 0 ) do {\
\n\t\t\t\t/ip firewall nat remove [find comment=\"VOD Script\"];\
\n\t\t\t}\
\n\t\t\t/ip firewall nat add action=dst-nat chain=dstnat comment=\"VOD Scr\
ipt\" dst-address-type=local in-interface=iptv-vlan2 to-addresses=\$ipadre\
ssnew\
\n\t\t\t:log info \"VODScript: IP address changed from \$ipadressold to \$\
ipadressnew !\"\
\n\t\t}\
\n\t}\
\n}"
# Programamos el script de VOD, para correr cada seis segundos
/system scheduler
add interval=6s name=vod on-event=vod policy=read,write start-time=startup
Vodafone Neba (Sin teléfono)
Tipo de conexión WAN: PPPoE
VLAN Internet: 24 (vlan 20, en algunos casos)
VLAN Teléfono: N/A
VLAN TV: N/A
Código:
# Añadimos la VLAN del servicio de internet (24 normalmente, aunque también puede venir por la 20)
/interface vlan add interface=ether1 name=vlan24 vlan-id=24
# Creamos la conexión PPPoE, sobre la vlan previamente creada. Usuario y contraseña extraidos de la configuración del router de Vodafone
/interface pppoe-client add disabled=no interface=vlan24 name=pppoe-out1 user=(usuario VF) password=(contraseña VF)
# Añadimos la nueva interfaz a la lista WAN
/interface list member add interface=pppoe-out1 list=WAN
ONT Huawei - Configurar VOIP
En HG8240H hay un botón en la parte superior derecha de la pantalla que lleva a las opciones avanzadas. En ambos casos iremos a la configuración de Voice y allí hay que poner los siguientes parámetros:
Outbond Proxy Server: 10.31.255.134
Outbond Proxy Server Port: 5070
Home Domain: telefonica.net
Local Port: 5060
Signalling Port: 1_VOIP_R_VID_3
Y pinchar en Apply
Ahora vamos a la parte de abajo de esa misma pantalla y añadimos/modificamos el usuario. Como datos hay que poner el número de teléfono en Registration User Name y Authentication User Name. Como password "ChangeMe" sin las comillas. Hay que pinchar en Apply.
Al volver a conectar la fibra, conectar el teléfono al puerto 1 y pasados un par de minutos debería estar operativo.
Configuración completa:
Es posible que muchas de las siguientes configuraciones sean aplicables a otras ONT Huawei. Asumo en todo momento que la configuración de partida de todo lo modificado a continuación es la que hay por defecto.
Para empezar, vamos a definir la VLAN de VoIP.
Una vez logueadosen la ONT nos vamos a WAN -> WAN Configuration y pulsamos en New:
- Enable WAN: Marcado
- Encapsulation Mode: IPoE
- Protocol Type: IPv4
- WAN Mode: Route WAN
- Service Type: VOIP
- Enable VLAN: Marcado
- VLAN ID: 3
- 802.1p Policy: Use the specified value
- 802.1p: 4
- MTU: 1500
- IP Acquisition Mode: DHCP
- Vendor ID y User ID: (En blanco)
Ahora vamos a configurar los parámetros básicos de SIP. Con esto debería ya funcionar, pero en los parámetros avanzados hay que cambiar unas cosillas también ya que los teléfonos que conectaremos al conector POTS de teléfono estan pensados para funcionar en una red telefónica europea. Luego lo veremos.
Ahora nos vamos a Voice -> VoIP Basic Configuration:
- Outbound Proxy Server Address: dhcp
- Outbound Proxy Server Port: 5070
- Address of the Standby Outbound Proxy Server: dhcp
- Port of the Standby Outbound Proxy Server: 5060
- Address of the Primary Proxy Server: telefonica.net
- Port of the Primary Proxy Server: 5060
- Address of the Standby Proxy Server: telefonica.net
- Port of the Standby Proxy Server: 5060
- Home Domain: telefonica.net
- Local Port: 5070
- Digitmap: (No modificar lo que hay por defecto)
- Digitmap Matching Mode: Min
- Registration Period: 600
- Signaling Port y Media Port: En ambos casos seleccionamos del menú desplegable la opción 1_VOIP_R_VID_3. Se trata de la VLAN que configuramos antes; puede que el número 1 del principio sea otro pero el resto debe ser lo indicado.
- Region: Spain
Seguimos abajo. Ahora vamos a configurar los parámetros específicos de nuestra línea telefónica. Debería aparecer la primera línea seleccionada en azul. Si no aparece nada pulsamos en New y ponemos lo siguiente:
- Enable User: Marcado
- URI: (En blanco)
- Registration User Name: (Nuestro número de teléfono de 9 dígitos)
- Associated POTS Port: 1
- Authentication User Name: (Nuestro número de teléfono de 9 dígitos)
- Password: (Nuestro número de teléfono de 9 dígitos)
Pulsamos en Apply. Si todo está bien puesto, deberíamos tener ya el teléfono funcionando. El LED "TEL" del ONT debería parpadear lento en verde y cuando le conectemos la fibra, al cabo de un par de minutos debería aparecer verde estático (y parpadeando cuando descolguemos el teléfono).
Finalmente, vamos a configurar los parámetros avanzados para configurar el contestador automático y otras cosas: Nos vamos a Voice -> SIP/H.248 Protocol Conversion y nos aseguramos que la opción del menú desplegable que aparece al lado de Voice es "SIP". Luego nos vamos a Voice -> VoIP Advanced Configuration:
- Enable Echo Cancellation: Marcado
- Fax Transmode: T.38
- Fax Switch Mode: Negotiation
- Profile Parameters: (No modificar lo que hay por defecto)
- Software Parameters: Seleccionamos la opción "User-defined" del menú desplegable y en el recuadro de al lado escribimos "1=3;8=0" sin las comillas.
- Digitmap Short Timer: 9
- Digitmap Long Timer: 9
- Shared User Mode: Disabled
- Multihoming Mode: Dual homing(automatic switchback)
- DTMF Transmission Mode: RFC2833
- RFC2833 Payload Type: 97
- Voice Server Type: IMS SIP Server
Y seguimos abajo de la línea en azul que aparecerá con nuestro número de teléfono:
- De la tabla de códecs de voz no cambiar nada, excepto en la fila G.722 en la opción Packet Time (ms) que seleccionamos 10 ms.
- DSP TX Gain: 0
- DSP RX Gain: 0
- Hotline (esto es el contestador): Enable: Marcado; Number: 1210@telefonica.net; Delay 10 (De hecho se puede poner cualquier valor, esto son los segundos que tardará a saltar el contestador cuando descolguéis el teléfono).
- Call Forwarding Unconditional: Si queréis que todas las llamadas recibidas se redirijan a cualquier otro número, marcad la casilla "Enable" y en el recuadro "Number" poned este número.
- Call Forwarding Busy: Si queréis que redirijan una llamada si en el momento de recibirla la línea está ocupada, marcad la casilla "Enable" y en el recuadro "Number" poned este número.
- Call Forwarding on No Reply: Si queréis que una llamada recibida se redirija a cualquier otro número en caso de no atenderla a tiempo, marcad la casilla "Enable" y en el recuadro "Number" poned este número.
- Call Waiting: Marcado
- Message Waiting Indicator: Marcado
- Three-party Call: Marcado
- Call Holding: Marcado
- Malicious Call Identification: Marcado
- Caller ID Display: Marcado
- Anonymous Call: Desmarcado
Y finalmente bajo "Physical Port Parameters":
- Port ID: 1
- Ringing Voltage: 50 Vrms
- DC Voltage: 0
- Port TX Gain: 0 dB
- Port RX Gain: 0 dB
- Lower Threshold for Flash Hooking Duration: 45
- Upper Threshold for Flash Hooking Duration: 140
- On-hook Confirmation Time: 150
- Impedance: Seleccionamos del menú desplegable la opción "Europe (Zin = 270 +750|150 nF)"
- Feed Current: 25
- CLIP Format: Mdmf-fsk
- FSK Transmission Delay: 600
- Clip Flow: After ring
- Enable DSP Template: Desmarcado
- Polarity Reversal on POTS Port: Marcado
- Display Time in CLIP: Marcado
- Enable DSP HighPass Filter: Marcado
Pulsamos en Apply y con esto queda el teléfono configurado. Apagamos la ONT, conectamos la Fibra y el teléfono (o la red telefónica al puerto POTS RJ-11) y todo debería funcionar.
Imágenes ONT Huawei:
ONT Huawei - Sustituir el HGU u ONT de Movistar por otra ONT de Huawei
Nosotros nos quedamos con los primeros 14 dígitos y nos quedaría el IDONT de la siguiente forma = F2016001234567 y esta numeración es la que necesitaremos para nuestros propósitos.
Máscara: 255.255.255.0
Puerta de enlace predeterminada: 192.168.100.1
Podéis mirar la etiqueta que lleva la ONT en la parte trasera para ver el user,password e IP de acceso.
Password: admintelecom
Pendrive con problemas de particiones
Con estas órdenes hacemos una sóla partición y la formateamos a ntfs ó fat32.
Abrimos C:\WINDOWS\system32\cmd.exe con botón derecho/ejecutar como administrador, ó la combinación de teclas Win+R.
Una vez en el símbolo del sistema escribimos:
>diskpart
>list disk
-NOTA: aseguraros de que número es el pendrive mirando los GB de este porque lo vais a formatear.
>select disk 1 (ejemplo) (número de tu pendrive según el listado anterior 1,2,3,etc)
>clean
>create partition primary
>format fs=NTFS quick
>assign
>exit
LAN Share : transfiere archivos de ordenador a ordenador en tu red local
Se trata de una aplicación simple para compartir archivos de PC a PC. Es una herramienta gratuita, de código abierto y multiplataforma que nos permitirá enviar archivos rápidamente entre equipos que ejecutan Windows y/o Ubuntu y aquellas distribuciones derivadas
Las transferencias de archivos se realizan de manera directa, PC a PC. Esto ocurrirá a través de nuestra red local o Wi-Fi. No se requieren configuraciones complicadas ni pensar lo más mínimo en los permisos de los usuarios. LAN Share es un cliente de transferencia de archivos de red escrito en C ++ y Qt para la interfaz gráfica.
Podremos utilizar el programa para enviar un archivo o carpeta de un equipo a otro que ejecute la aplicación. La aplicación funciona tanto en Windows como en Ubuntu. Esto significa que podremos utilizarla para transferir archivos de Windows a Ubuntu, de Ubuntu a Windows, de Windows a Windows y evidentemente también podremos hacerlo de Ubuntu a Ubuntu.
Al utilizar este programa, no encontraremos servidores de terceros, ni servicios en la nube, ni carpetas intermedias, ni complicadas configuraciones de protocolos involucrados en el traspaso de información. Tan solo tendremos que instalar la aplicación en cada equipo que queramos utilizar, usar el menú ‘Send’ para seleccionar el o los archivo/s o carpeta/s que necesitemos enviar y seleccionar el equipo de destino.
Una cosa importante a tener en cuenta, que es el único requisito importante, es que los equipos involucrados estén en la misma red local o conexión Wi-Fi.
Características generales de LAN Share
Funciona directamente, PC a PC. Sin puntos intermedios.
Carece de funciones avanzadas.
Es más rápido que si utilizásemos un servicio en la nube como Dropbox.
Nos va a permitir enviar archivos o carpetas, sin la necesidad de que deban estar comprimidos, entre diferentes sistemas operativos.
No tiene límites de tamaño en los archivos enviados.
La interfaz de usuario que ofrece resulta muy simple y directa.
La ventana principal del programa se divide por la mitad. En la parte superior encontraremos los archivos enviados y los archivos recibidos los encontraremos en la parte inferior. Ambas partes nos van a mostrar barras de progreso en tiempo real y metadatos cuando los archivos se envían y/o se reciben.
El botón Settings ofrece acceso a opciones para:
Establecer o cambiar el nombre del dispositivo.
Vamos a poder establecer o cambiar los puertos.
Indicar el tamaño del búfer de archivo.
Seleccionar una carpeta para las descargas.
Descargar LAN Share
Los instaladores para Windows y Ubuntu están disponibles en la página Github del proyecto. No tendremos más que dirigirnos a esa página y allí descarguemos la última versión del paquete .deb.
Una vez terminada la descarga del paquete, podremos utilizar la utilidad de software de Ubuntu para la instalación. Si somos más amigos de la terminal (Ctrl+Alt+T), abrimos una y escribimos en ella:
sudo dpkg -i lanshare_1.2.1-1_amd64.deb
Si preferimos no instalar nada, podremos utilizar el archivo .AppImage. Este lo podremos encontrar en la página de GitHub del proyecto.
https://github.com/abdularis/LAN-Share/releases
Si quieres transferir archivos entre equipos de una forma rápida y sencilla, esta es una de las mejores opciones.
Bloqueo WhatsApp wifi
Puertos de WhatsApp.
Diferentes rastreos del uso de WhatsApp desvelan los puertos mediante los que la app se conecta al servidor.
Es otra opción más: bloquear dichos puertos en el router.
Serían los siguientes:
-TCP 5222
-TCP 5223
-TCP 5228
-TCP 5242
Todas estas opciones tenemos para bloquear el uso de WhatsApp en una red WiFi. Para ello, como decimos, necesitamos acceso al router o al firewall que haya en dicha red mediante alguna forma.
